home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Commodore Disc 1
/
Commodore_Disc_01_19xx_-_de.d64
/
koenig arthus 64
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2022-10-26
|
16KB
|
610 lines
10 rem koenig arthus ============64
20 rem (c) commodore welt team =
30 rem torsten seibt =
40 rem ============================
50 rem =
60 rem =
70 rem version 2.0 40z/ascii =
80 rem vc-64 + vc1530/1541 =
90 rem ============================
100 wh$=chr$(5):cv$=chr$(8)
110 ce$=chr$(9):rt$=chr$(13)
120 so$=chr$(14):cd$=chr$(17)
130 rn$=chr$(18):ho$=chr$(19)
140 de$=chr$(20):re$=chr$(28)
150 ch$=chr$(29):gr$=chr$(30)
160 bl$=chr$(31):sp$=chr$(32)
170 oe$=chr$(129):fa$=chr$(133)
180 fc$=chr$(134):fe$=chr$(135)
190 fg$=chr$(136):fb$=chr$(137)
200 fd$=chr$(138):ff$=chr$(139)
210 fh$=chr$(140):sr$=chr$(141)
220 gb$=chr$(142):bk$=chr$(144)
230 cu$=chr$(145):rf$=chr$(146)
240 cl$=chr$(147):in$=chr$(148)
250 br$=chr$(149):hr$=chr$(150)
260 gu$=chr$(151):gz$=chr$(152)
270 hg$=chr$(153):hb$=chr$(154)
280 gd$=chr$(155):pu$=chr$(156)
290 ct$=chr$(157):ye$=chr$(158)
300 cy$=chr$(159):sq$=chr$(160)
310 z1$=chr$(96):z2$=chr$(98)
320 z3$=chr$(123):z4$=chr$(171)
330 z5$=chr$(173):z6$=chr$(174)
340 z7$=chr$(176):z8$=chr$(177)
350 y1$=chr$(178):y2$=chr$(179)
360 y3$=chr$(189)
370 forq=1to37:q3$=q3$+z1$:nextq
380 forq=1to6:q6$=q6$+z1$:nextq
390 forq=1to7:q7$=q7$+z1$:nextq
400 forq=1to8:q8$=q8$+z1$:nextq
410 forq=1to9:q9$=q9$+z1$:nextq
420 v1$=chr$(58):v2$=chr$(105)
430 v3$=chr$(117):v4$=chr$(127)
440 v5$=chr$(161):v6$=chr$(162)
450 v7$=chr$(168):v8$=chr$(169)
460 v9$=chr$(188)
470 w1$=chr$(190):w2$=chr$(191)
480 goto590
490 forzz=1to40:printbl$chr$(163);:nextzz:return
500 print" "bk$rn$" weiter mit space "
510 geta$:ifa$=""then510
520 return
530 printcl$cv$gb$
540 form=1to40:printbl$chr$(175);:nextm
550 forj=1to40:printye$chr$(164);:nextj
560 printye$rn$"* koenig arthus *"rf$
570 forn=1to40:printbl$chr$(183);:nextn
580 return
590 y(0)=1200
600 databauer,arbeiter,herr,baron,graf,herzog,prinz,koenig
610 dataholstein,sachsen,boehmen,schwaben,bayern,schlesien,arelat,pommern
620 restore:poke53281,0:poke53280,0:gosub530
630 fora=1to8:reada$:next
640 printcd$wh$"anzahl der mitspieler <1-8>"
650 print:inputf
660 iff<1orf>8then620
670 print:fora=1tof:readt$(a)
680 printbl$"wer soll in ";t$(a);" herrschen"
690 print:inputn$:print
700 iflen(n$)>10then680
710 n$(a)=n$+" von "+t$(a)
720 g(a)=10
730 h(a)=10
740 i(a)=10
750 j(a)=2
760 o(a)=1220+int(rnd(1)*30)
770 k(a)=1500
780 l(a)=12000
790 r(a)=4000
800 t(a)=1
810 u(a)=1
820 n(a)=5
830 p(a)=25
840 q(a)=5
850 m(a)=20
860 s(a)=1800
870 next
880 fora=1tof
890 restore
900 b=t(a)
910 forc=1tob
920 readt$(a)
930 next
940 next
950 gosub530
960 printcd$ye$"bedienungsanleitung bekannt (j/n)"
970 print:inputa$
980 ifleft$(a$,1)="n"thengosub5690
990 poke53281,0:poke53280,0
1000 gosub530:printspc(45)bl$"1. "wh$"blutiger anfaenger"cd$
1010 printtab(5)bl$"2. "ye$"gesponserter amateur"cd$
1020 printtab(5)bl$"3. "pu$"bezahlter profi"cd$
1030 printtab(5)bl$"4. "gr$"meister aller klassen"
1040 printcd$ye$"ein wie guter spieler sind sie <1-4>"
1050 print:inputu
1060 u(0)=int(u)
1070 ifu<1thenu(0)=1
1080 ifu>4thenu(0)=4
1090 u(0)=u(0)+5
1100 e=e+1
1110 ift(e)=-1thene=e+1
1120 ift(1)<1andt(2)<1andt(3)<1andt(4)<1andt(5)<1andt(6)<1andt(7)<1andt(8)<1then100
1130 ife>fthene=0:y(0)=y(0)+1:goto1100
1140 ify(0)>o(e)then1100
1150 ify(0)=o(e)then1330
1160 gosub1600
1170 gosub2330
1180 gosub3110
1190 gosub2740
1200 gosub3770
1210 gosub4630
1220 gosub5010
1230 goto1100
1240 poke53281,6:poke53280,4
1250 printcl$bk$rn$" land hoef- leib- kirche haend- sol- ";
1260 print" qm/2 linge eigene klerus ler daten "
1270 fora=1tof:printgz$t$(a)" "n$(a)
1280 l$=str$(l(a))
1290 l$=wh$+right$(l$,len(l$)-1)
1300 printl$tab(6)n(a)tab(12)s(a)tab(19)q(a)tab(26)m(a)tab(33)p(a)
1310 next
1320 print:gosub500:return
1330 poke53281,2:poke53280,2
1340 printcl$rn$bk$v3$;:forp=1to38:printz1$;:nextp:printv2$;
1350 printz2$" eine schreckliche nachricht traf ein "z2$;
1360 printchr$(106);:forp=1to38:printz1$;:nextp:printchr$(107)
1370 printcd$ye$t$(e)" "n$(e)
1380 print"ist gerade "
1390 t(e)=-1:y=int(rnd(8)*8)+1
1400 ify(0)>1250thenprint"nach langer regierung gestorben worden.":goto1460
1410 ify<4thenprint"im schweren schneesturm verschollen."
1420 ify=5thenprint"an cholera (vibrio cholerae) gestorben."
1430 ify=4thenprint"beim sturz vom pferd leider toedlich verunglueckt."
1440 ify=6thenprint"von attentaetern ermordet worden."
1450 ify>6thenprint"an unbekannter krankheit (maetresse) gestorben."
1460 print:eg=1
1470 gosub500
1480 gosub3770
1490 gosub1240
1500 eg=0
1510 goto1100
1520 i1=int(i1):return
1530 c1=int(c1):return
1540 s1=int(s1):return
1550 k(e)=int(k(e)):return
1560 z=(int(rnd(a)*a)+1)*s(e)/100:z2=z:printbl$int(z2)"neugeborene leibeigene."
1570 print:s(e)=s(e)+z2:return
1580 z=(int(rnd(a)*a)+1)*s(e)/100:z2=z:printre$int(z2)"leibeigene gestorben."
1590 print:s(e)=s(e)-z2:return
1600 w=(int(rnd(5)*5)+2+int(rnd(6)*6))/2
1610 onwgoto1620,1630,1640,1650,1660
1620 w$="duerre":goto1670
1630 w$="schlechtes wetter":goto1670
1640 w$="durchschnittliches wetter":goto1670
1650 w$="gutes wetter":goto1670
1660 w$="phantastisches wetter":goto1670
1670 r=int(rnd(50)*50)+1
1680 r(e)=(r(e)*100-r(e)*r)/100
1690 x=l(e):y=(s(e)-d(e)*100)*5
1700 ify<0theny=0:goto1720
1710 ify<xthenx=y
1720 y=r(e)*2:ify<xthenx=y
1730 y=w-.5:h1=x*y:r(e)=r(e)+h1
1740 d1=n(e)*100+c(e)*40+m(e)*30+p(e)*10+s(e)*5
1750 l=(3*w+int(rnd(6)*6)+2+int(rnd(6)*6)+10)/10
1760 ifh1<1theny=2:goto1780
1770 y=d1/h1:ify>2theny=2
1780 ify<.8theny=.8
1790 l=l*y:l=int(l*10):l=l/10
1800 z=6-w
1810 g=(z*5+int(rnd(5)*5)+int(rnd(5)*5))/5*y*20
1820 return
1830 print
1840 printbr$"von ihrem lagerweizen wurde von ratten"
1850 printr" prozent gefressen"
1860 printbl$w$
1870 printbk$"* jahresernte weizen:"int(h1)"scheffel *"
1880 print:ifk(e)<32766thengosub1550
1890 r$=str$(int(r(e))):r$=right$(r$,len(r$)-1):ifr(e)<0thenr$=" 0"
1900 d$=str$(int(d1)):d$=right$(d$,len(d$)-1)
1910 g$=str$(int(g)):g$=" "+g$:l$=str$(l):l$=" "+l$
1920 k$=str$(int(k(e)))
1930 printbk$z7$q7$y1$q6$y1$q7$y1$q8$y1$q6$z6$;
1940 printz2$"weizen "z2$"weizen"z2$"weizen "z2$"land "z2$"$$$$$$"z2$;
1950 printz2$"reserve"z2$"bedarf"z2$"preis "z2$"preis "z2$" "z2$;
1960 printbk$z4$q7$z3$q6$z3$q7$z3$q8$z3$q6$y2$;
1970 printz2$r$tab(8)z2$d$tab(15)z2$g$tab(23)z2$l$tab(32)z2$k$tab(39)z2$;
1980 printbk$z4$q7$z8$q6$z3$q7$z3$q8$z3$q6$y2$;
1990 printz2$"scheffel "z2$"1000 sl"z2$"morgen "z2$"gold "z2$;
2000 printbk$z5$q7$z1$q6$z8$q7$z8$q8$z8$q6$y3$;
2010 return
2020 j=(j(e)*300-500)*t(e)
2030 onj(e)goto2040,2060,2080,2100
2040 j$="gnaedig"
2050 goto2110
2060 j$="fair"
2070 goto2110
2080 j$="ungerecht"
2090 goto2110
2100 j$="bestechl."
2110 y=150-g(e)-h(e)-i(e)
2120 ify<1theny=1
2130 c1=(n(e)*180+q(e)*75+m(e)*20)*(y/100)+u(e)*100
2140 s1=(n(e)*50+m(e)*25+u(e)*19)*(y/100)*(5-j(e))/2
2150 i1=n(e)*250+u(e)*20+(10*j(e)*n(e))*(y/100)
2160 c1=c1*g(e)/100
2170 ifc1<32760thengosub1530
2180 s1=s1*h(e)/100
2190 ifs1<32760thengosub1540
2200 i1=i1*i(e)/100
2210 ifi1<32760thengosub1520
2220 printbk$z7$q3$z6$
2230 printz2$"steuer einkuenfte"j+c1+s1+i1"goldstuecke."tab(38)z2$
2240 printbk$z4$q9$y1$q7$y1$q9$y1$q9$y2$
2250 printz2$"zoll "z2$"verkauf"z2$"einkommen"z2$"gerichts-"z2$
2260 printz2$"abgaben "z2$"steuer "z2$"steuer "z2$"wesen "z2$
2270 printbk$z4$q9$z3$q7$z3$q9$z3$q9$y2$
2280 printz2$" "g(e)ct$"%"tab(10)z2$" "h(e)ct$"%";
2290 printtab(18)z2$" "i(e)ct$"%"tab(28)z2$j$tab(38)z2$
2300 printz2$" "c1tab(10)z2$" "s1tab(18)z2$" "i1tab(28)z2$" "jtab(38)z2$
2310 printbk$z5$q9$z8$q7$z8$q9$z8$q9$y3$
2320 return
2330 poke53280,7:poke53281,7
2340 printcl$bk$t$(e)" "n$(e)
2350 gosub490
2360 gosub1830
2370 printcd$"[1] kaufe weizen [3] kaufe land"
2380 print"[2] verkaufe weizen [4] verkaufe land"
2390 printcd$bl$"[0] weiterspielen [0-4] bitte waehlen"
2400 inputi
2410 ifi>4then2330
2420 ifi<1thenreturn
2430 onigoto2440,2540,2610,2670
2440 printbk$"wieviel weizen wollen sie kaufen"
2450 inputi
2460 ifi<1then2490
2470 k(e)=k(e)-(i*g/1000)
2480 r(e)=r(e)+i
2490 printcl$bk$t$(e)" "n$(e)
2500 gosub490
2510 printtab(80)
2520 print:gosub1880
2530 goto2370
2540 printbk$"wieviel weizen wollen sie verkaufen"
2550 inputi
2560 ifi<1then2490
2570 ifi>r(e)thenprintre$"sie haben ja gar nicht so viel !":goto2540
2580 k(e)=k(e)+(i*g/1000)
2590 r(e)=r(e)-i
2600 goto2490
2610 printpu$"wieviele morgen wollen sie kaufen"cd$
2620 inputi
2630 ifi<0then2490
2640 l(e)=l(e)+i
2650 k(e)=k(e)-(i*l)
2660 goto2490
2670 printpu$"wieviele morgen wollen sie verkaufen"
2680 inputi
2690 ifi<0then2490
2700 ifi>(l(e)-5000)thenprintre$"sie haben ja gar nicht so viel !":goto2670
2710 l(e)=l(e)-i
2720 k(e)=k(e)+(i*l)
2730 goto2490
2740 printcl$:poke53281,5:poke53280,6
2750 printye$t$(e)" "n$(e)
2760 gosub490
2770 print:gosub2020
2780 printcd$"[1] zollabgaben [3] einkommensteuer"
2790 print"[2] verkaufsteuer [4] gericht"
2800 print"[0] = weiter "wh$"[0-4] = waehlen sie"
2810 inputi
2820 ifi>4then2800
2830 ifi<1then3070
2840 onigoto2850,2900,2940,2980
2850 printwh$"neue zollabgaben (0-100)"
2860 inputi
2870 ifi>100theni=100
2880 ifi<0theni=0
2890 g(e)=i:goto2740
2900 printwh$"neue verkaufsteuer (0-50)"
2910 inputi
2920 if(i>50)or(i<0)theni=5
2930 h(e)=i:goto2740
2940 printwh$"neue einkommensteuer (0-25)"
2950 inputi
2960 if(i<0)or(i>25)theni=0
2970 i(e)=i:goto2740
2980 printwh$cl$:forq=1to40:printchr$(45);:nextq
2990 printrn$spc(16)"gericht"
3000 forq=1to40:printchr$(45);:nextq
3010 printcd$"[1] gnaedig [3] ungerecht"
3020 printcd$"[2] fair [4] bestechlich"
3030 printcd$bl$"welche stufe"
3040 inputi
3050 if(i>4)or(i<1)theni=1
3060 j(e)=i:goto2740
3070 k(e)=k(e)+c1+s1+i1+j
3080 ifk(e)<0thenk(e)=k(e)*1.5
3090 ifk(e)<(-10000*t(e))then5360
3100 return
3110 printcl$bk$t$(e)" "n$(e)
3120 gosub490
3130 printtab(120):gosub1880
3140 printcd$bl$"wieviel weizen geben sie ihren leuten"
3150 print"zum taeglichen verbrauch"cd$
3160 inputg
3170 ifg<(r(e)/4)thenprintre$"sie muessen mindestens 25% freigeben":goto3140
3180 ifg>(r(e)*.75)thenprintre$"sie muessen mindestens 25% aufbewahren":goto3140
3190 r(e)=r(e)-g
3200 printcl$bk$t$(e)" "n$(e)
3210 forzz=1to40:printchr$(163);:nextzz
3220 poke53281,1:poke53280,1
3230 z=g/d1-1
3240 ifz>0thenz=z/2
3250 ifz>.25thenz=z/10+.25
3260 z2=50-g(e)-h(e)-i(e)
3270 ifz2<0thenz2=z2*j(e)
3280 z2=z2/10
3290 ifz2>0thenz2=z2+3-j(e)
3300 z=z+(z2/10)
3310 ifz>.5thenz=.5
3320 ifg<(d1-1)then3580
3330 a=7:gosub1560
3340 a=3:gosub1580
3350 if(g(e)+h(e))<35thenm(e)=n(e)+int(rnd(2)*2):q(e)=q(e)+int(rnd(3)*3)
3360 ifi(e)<int(rnd(20)*20)+1thenn(e)=n(e)+int(rnd(2)*2):q(e)=q(e)+int(rnd(3)*3)
3370 ifg<(d1+d1*.3)then3510
3380 z2=s(e)/1000
3390 z=(g-d1)/d1*10
3400 z=z*z2*int(rnd(25)*25+1)+int(rnd(40)*40+1)
3410 ifz>32000thenz=32000
3420 z2=z:z=int(rnd(4)*z2)+1
3430 printcd$bk$z"leibeigene sind eingewandert"cd$
3440 s(e)=s(e)+z
3450 z2=z/5
3460 z=int(rnd(5)*z2)+1
3470 ifz>50thenz=50
3480 m(e)=m(e)+z
3490 n(e)=n(e)+1
3500 q(e)=q(e)+2
3510 ifj(e)<3then3570
3520 j1=s(e)/100*(j(e)-2)*(j(e)-2)
3530 j1=int(rnd(8)*j1)+1
3540 s(e)=s(e)-j1
3550 printcd$cy$j1"leibeigene sind wegen ungerechter"
3560 print"herrschaft ausgewandert"
3570 goto3640
3580 x=(d1-g)/d1*100-9
3590 ifx>65thenx=65
3600 ifx<0thenx2=0:x=0
3610 a=3:gosub1560
3620 a=x2+8:gosub1580
3630 goto3510
3640 z=a(e)*75
3650 k(e)=k(e)+z
3660 ifz>0thenprintcd$bl$" markt brachte"z"golddstuecke ein."cd$
3670 ifs(e)<32766thens1=s(e):gosub1540:s(e)=s1
3680 z=d(e)*(55+int(rnd(250)*250+1))
3690 ifz>0thenk(e)=k(e)+z:printpu$" muehle brachte"z"goldstuecke ein."cd$
3700 z=p(e)*3:printgr$" armee kostet"z"goldstuecke."cd$:k(e)=k(e)-z
3710 if(l(e)/1000)>p(e)then5470
3720 if(l(e)/500)<p(e)then3760
3730 fora=1tof:ifa=ethen3750
3740 ifp(a)>(p(e)*2.4)then5470
3750 next
3760 print:gosub500:return
3770 poke53281,5:poke53280,4
3780 printcl$bk$
3790 l2=(l(e)/1000)
3800 ifl2<10thenx=30:y=20:goto3870
3810 ifl2<30thenx=25:y=17:goto3870
3820 ifl2<50thenx=20:y=14:goto3870
3830 ifl2<70thenx=15:y=11:goto3870
3840 ifl2<90thenx=10:y=08:goto3870
3850 ifl2<110thenx=5:y=5:goto3870
3860 x=1:y=2:goto3870
3870 a$=bk$:fora=1toy:a$=a$+cd$:nexta
3880 fora=1tox:a$=a$+ch$:nexta
3890 fora=xto39:a$=a$+chr$(118):next
3900 printho$a$
3910 a$=bk$:fora=1toy-1:a$=a$+cd$:next
3920 fora=1tox:a$=a$+ch$:next
3930 b$=a$+ct$:c$=a$:d$=a$:e$=a$:f$=a$:g$=a$
3940 fora=y-1to23:a$=a$+cd$+ct$+chr$(118):next
3950 printho$a$;
3960 c1$=br$+cu$+w2$+w2$+w1$+cd$+ct$+ct$+ct$+rn$+v5$
3970 c2$=sp$+cd$+ct$+ct$+v5$+sp$+rf$
3980 c1$=c1$+c2$
3990 c3$=br$+cu$+w2$+w2$+w1$+v9$+rn$+w2$
4000 c4$=w2$+cd$+ct$+ct$+ct$+ct$+ct$+ct$+v5$+sp$+rf$
4010 c5$=v7$+v7$+rn$+sp$+rf$+v5$+cd$+ct$+ct$+ct$+ct$+ct$+ct$
4020 c6$=rn$+w1$+p$+sp$+sp$+sp$+sp$+v9$+rf$
4030 c3$=c3$+c4$+c5$+c6$
4040 if(p(e)-5)<(l(e)/1000)then4080
4050 if(p(e)/2)<(l(e)/1000)then4070
4060 printho$b$c3$:goto4080
4070 printho$b$c1$
4080 fora=y-2toy+int((23-y)*.8)
4090 c$=c$+cd$:next
4100 fora=x+1tox+int((39-x)*.1)
4110 c$=c$+ch$:next:c$=c$+ch$
4120 z=c(e)+1:ifz>7thenz=7
4130 ifz=0then4210
4140 c$(2)=bl$+v9$+rn$+v6$+rf$+w1$+cu$+ct$+ct$+ct$+rn$+pu$+v8$+sp$+v4$
4150 c$(3)=c$(2)+cu$+ct$+ct$+rf$+wh$+z3$:c$(1)=" "
4160 c$(4)=c$(3)+cd$+cd$+bl$+rn$+v6$+v6$+v6$+v6$+rf$+w1$
4170 c$(5)=c$(4)+cu$+ct$+ct$+ct$+rn$+pu$+v8$+sp$+v4$
4180 c$(6)=c$(5)+cu$+ct$+ct$+rf$+wh$+z3$
4190 c$(7)=c$(6)+ct$+ct$+ct$+bk$+rf$+z3$+cd$+ct$+rn$+ye$
4200 c1$=c$(z):printho$;c$;c1$;
4210 fora=y-2toy+int((23-y)*.8)
4220 d$=d$+cd$:next
4230 fora=xtox+int((39-x)*.5)
4240 d$=d$+ch$:next
4250 ifb(e)=0then4320
4260 ifl(e)<10000thend$=d$+ct$+ct$
4270 c$(1)=rn$+bk$+v1$+v2$+cu$+ct$+ct$+pu$+v8$+v4$
4280 c$(2)=c$(1)+rf$+ye$+v3$+v2$+cd$+ct$+ct$+br$+rn$+z7$+z6$
4290 c$(3)=c$(2)+br$+rn$+v1$+v2$+cu$+ct$+ct$+pu$+v8$+v4$
4300 a=b(e):ifa>3thena=3
4310 printho$d$c$(a)
4320 fora=ytoy+int((25-y)*.3)
4330 e$=e$+cd$:next
4340 fora=xtox+int((39-x)*.1)
4350 e$=e$+ch$:next
4360 fg=a(e):iffg>40-athenfg=40-a
4370 ifa(e)=0then4390
4380 fora=1tofg:e$=e$+rf$+bl$+chr$(120):next
4390 printho$e$;
4400 fora=ytoy+int((25-y)*.49)
4410 f$=f$+cd$:next
4420 fora=xtox+int((39-x)*.14)
4430 f$=f$+ch$:next
4440 fg=d(e):iffg>40-athenfg=40-a
4450 iffg=0then4470
4460 fora=1tofg:f$=f$+ye$+rf$+chr$(97):next
4470 printho$f$;
4480 z=s(e)-d(e)*100
4490 g$=g$+cd$
4500 ifz<0thenz=.1
4510 z=z*5/l(e)*10
4520 ifz>10thenz=10
4530 z=10-z
4540 z=int((24-y)*(z/10))+1
4550 fora=1toz
4560 g$=g$+cd$:next
4570 fora=1to(39-x)
4580 g$=g$+ch$:next
4590 printho$g$bl$rn$chr$(122);
4600 printho$cd$cd$wh$tab(14)"jahr:"y(0)
4610 ifeg=1thenprintho$ye$tab(165)t$(e)" "n$(e)
4620 printho$;:gosub500:return
4630 printcl$;:poke53280,9:poke53281,8
4640 printbk$t$(e)" "n$(e)
4650 gosub490
4660 printbl$"staatsinvestitionsmoeglichkeiten:"cd$
4670 printbk$"[1] markt 1000 goldstuecke"
4680 print"[2] muehle 2000 goldstuecke"
4690 print"[3] palast (teil) 3000 goldstuecke"
4700 print"[4] kirche (teil) 5000 goldstuecke"
4710 print"[5] ausgest. armeeinh. 500 goldstuecke"
4720 printcd$ye$"sie haben"int(k(e))"goldstuecke."cd$
4730 printwh$"[0] = fortfahren / [6] = spielstand"
4740 input"ihre wahl";i
4750 ifi<1thenreturn
4760 ifi>5thengosub1240:goto4630
4770 onigoto4820,4780,4870,4920,4970
4780 d(e)=d(e)+1
4790 k(e)=k(e)-2000
4800 u(e)=u(e)+.25
4810 goto4630
4820 a(e)=a(e)+1
4830 m(e)=m(e)+5
4840 k(e)=k(e)-1000
4850 u(e)=u(e)+.1
4860 goto4630
4870 b(e)=b(e)+1
4880 n(e)=n(e)+int(rnd(2)*2)+1
4890 k(e)=k(e)-3000
4900 u(e)=u(e)+.5
4910 goto4630
4920 c(e)=c(e)+1
4930 q(e)=q(e)+int(rnd(6)*6)+1
4940 k(e)=k(e)-5000
4950 u(e)=u(e)+1
4960 goto4630
4970 p(e)=p(e)+20
4980 s(e)=s(e)-20
4990 k(e)=k(e)-500
5000 goto4630
5010 printtab(80)
5020 z=0
5030 a=a(e):gosub5270
5040 a=b(e):gosub5270
5050 a=c(e):gosub5270
5060 a=d(e):gosub5270
5070 a=k(e)/5000:gosub5270
5080 a=l(e)/6000:gosub5270
5090 a=m(e)/50:gosub5270
5100 a=n(e)/5:gosub5270
5110 a=p(e)/50:gosub5270
5120 a=q(e)/10:gosub5270
5130 a=s(e)/2000:gosub5270
5140 a=u(e)/5:gosub5270
5150 a=z/u(0)-j(e)
5160 a=int(a)
5170 ifa>8thena=8
5180 if(y(0)+2)=o(e)thent(e)=t(e)+1
5190 ift(e)>=athen5260
5200 t(e)=a
5210 restore
5220 forb=1to(t(e)+v(e))
5230 readt$(e)
5240 next
5250 ift(e)=8then5310
5260 return
5270 ifa>10thena=10
5280 a=int(a)
5290 z=z+a
5300 return
5310 printcl$;:poke53280,6:poke53281,14
5320 eg=1
5330 gosub3770
5340 gosub1240
5350 clr:goto10
5360 poke53280,2:poke53281,2:printcl$cy$;
5370 printt$(e)" "n$(e)" ist bankrott"cd$
5380 printwh$"die glaeubiger haben sich das meiste "
5390 print"ihres vermoegens angeeignet."cd$
5400 print"viele leibeigene verlassen das land"cd$
5410 gosub500
5420 a(e)=0:b(e)=0:c(e)=0:d(e)=0
5430 l(e)=6000:u(e)=1:k(e)=100
5440 s(e)=int(s(e)*rnd(1))
5450 ifr(e)>5000thenr(e)=5000
5460 return
5470 z=0:fora=1tof
5480 ifa=ethen5520
5490 ifp(a)<p(e)then5520
5500 ifp(a)<(1.2*(l(a)/1000))then5520
5510 ifp(a)>p(z)thenz=a
5520 next
5530 ifz<>0then5570
5540 t$(0)="baron":n$(0)="igor v. fronkensteein"
5550 a1=1001+int(rnd(8)*9000)
5560 goto5580
5570 a1=p(z)*1000-l(z)/3
5580 ifa1>(l(e)-5000)thena1=(l(e)-5000)/2
5590 printre$:forzz=1to40:printz1$;:nextzz
5600 printbk$t$(z)" "n$(z)" greift an und"
5610 print"besetzt"a1"morgen land!"
5620 l(z)=l(z)+a1:l(e)=l(e)-a1
5630 z=int(rnd(4)*40)+1:ifz>(p(e)-15)thenz=p(e)-15
5640 printt$(e)" "n$(e)
5650 print"verliert"z"soldaten."
5660 printbk$:forzz=1to40:printz1$;:nextzz
5670 p(e)=p(e)-z
5680 print:gosub500:return
5690 poke53280,11:poke53281,15
5700 printcl$bl$" "rn$" koenig arthus "cd$bk$
5710 print"sie sind der herrscher eines verarmten "
5720 print"geschlechtes aus dem 13. jahrhundert sie";
5730 print"muessen durch kauf, verkauf von land und";
5740 print"weizen, festlegung von steuern, zuwei-"
5750 print"sung von weizen, anschaffung von guetern";
5760 print"ihr geschick im regieren beweisen. je "
5770 print"besser sie sind, desto schneller er-"
5780 print"reichen sie das ziel in der regierungs-"
5790 print"hierarchie: "re$"koenig"bk$" zu werden."
5800 print"denn sieger ist, wer zuerst koenig ist."
5810 print"aber vorsicht, denn das leben in jener"
5820 print"zeit war kurz, und schon mancher ist"
5830 print"vor dem ziel auf der strecke geblieben!"cd$
5840 print"der computer zeichnet eine karte ihres"
5850 print"landes. die groesse der burg im eck"
5860 print"zeigt die angemessenheit ihrer armee."
5870 print"wenn sie schrumpft, dann ruesten sie"
5880 print"mehr soldaten aus!"cd$
5890 print" "bk$rn$" weiter mit space "
5900 getb$:ifb$=""then5900
5910 printcl$bl$" "rn$" koenig arthus "cd$bk$
5920 print"wenn die markierung die mauer beruehrt,"
5930 print"wird im ganzen land produziert, sonst"
5940 print"benoetigen sie noch mehr leibeigene als"
5950 print"arbeiter auf den bauernhoefen."
5960 print"hoehere steuern bringen mehr geld, aber"
5970 print"verringern das wirtschaftswachstum."
5980 print"sie koennen schulden machen, aber seien"
5990 print"sie vorsichtig, denn die zinsen liegen"
6000 print"bei 50% pro jahr und sie koennten daran"
6010 print"leicht bankrott gehen!"
6020 printcd$:gosub500:return
6030 rem koenig arthus ==========64
6040 rem 38911 bytes memory ====
6050 rem 16032 bytes program ====
6060 rem 00805 bytes variables ====
6070 rem 01360 bytes arrays ====
6080 rem 10048 bytes strings ====
6090 rem 02474 bytes free ====